Oracle nos suministra un paquete público con el cual podemos enviar mensajes desde subprogramas almacenados, paquetes y disparadores, colocarlos en un buffer y leerlos desde otros subprogramas almacenados, paquetes o disparadores.

SQL*Plus permite visualizar los mensajes que hay en el buffer, por medio del comando SET SERVEROUTPUT ON. La utilización fundamental de este paquete es para la depuración de nuestros subprogramas.

Veamos uno a uno los subprogramas que nos suministra este paquete:

Habilita las llamadas a los demás subprogramas. No es necesario cuando está activada la opción SERVEROUTPUT. Podemos pasarle un parámetro indicando el tamaño del buffer.
```
ENABLE
ENABLE( buffer_size IN INTEGER DEFAULT 2000);
```
Deshabilita las llamadas a los demás subprogramas y purga el buffer. Como con ENABLE no es necesario si estamos usando la opción SERVEROUTPUT.
```
DISABLE
DISABLE();
```
Coloca elementos en el buffer, los cuales son convertidos a VARCHAR2.
```
PUT
PUT(item IN NUMBER);
PUT(item IN VARCHAR2);
PUT(item IN DATE);
```

Coloca elementos en el buffer y los termina con un salto de línea.

PUT_LINE
PUT_LINE(item IN NUMBER);
PUT_LINE(item IN VARCHAR2);
PUT_LINE(item IN DATE);

Coloca un salto de línea en el buffer. Utilizado cuando componemos una línea usando varios PUT.
```
NEW_LINE
NEW_LINE();
```
Lee una línea del buffer colocándola en el parámetro line y obviando el salto de línea. El parámetro status devolverá 0 si nos hemos traído alguna línea y 1 en caso contrario.
```
GET_LINE
GET_LINE(line OUT VARCHAR2, status OUT VARCHAR2);
```
Intenta leer el número de líneas indicado en numlines. Una vez ejecutado, numlines contendrá el número de líneas que se ha traído. Las líneas traídas las coloca en el parámetro lines del tipo CHARARR, tipo definido el paquete DBMS_OUTPUT como una tabla de VARCHAR2(255).
```
GET_LINES
GET_LINES(lines OUT CHARARR, numlines IN OUT INTEGER);
```

Ejercicio resuelto

Debes crear un procedimiento que visualice todos los agentes, su nombre, nombre de la familia y/o nombre de la oficina a la que pertenece.

Retroalimentación

CREATE OR  REPLACE PROCEDURE lista_agentes IS
     CURSOR cAgentes IS SELECT identificador, nombre,familia, oficina FROM agentes;
     fam familias.nombre%TYPE;
     ofi oficinas.nombre%TYPE;
     num_ag INTEGER := 0;
BEGIN
     DBMS_OUTPUT.ENABLE( 1000000 );
     DBMS_OUTPUT.PUT_LINE('Agente              |Familia             |Oficina             ');
     DBMS_OUTPUT.PUT_LINE('---------------------------------------------------------------');
     FOR ag_rec IN cAgentes LOOP
          IF (ag_rec.familia IS NOT NULL) THEN
               SELECT nombre INTO fam FROM familias WHERE identificador = ag_rec.familia;
               ofi := NULL;
               DBMS_OUTPUT.PUT_LINE(rpad(ag_rec.nombre,20) || '|' || rpad(fam,20) || '|' || rpad(ofi,20));
               num_ag := num_ag + 1;
          ELSIF (ag_rec.oficina IS NOT NULL) THEN
               SELECT nombre INTO ofi FROM oficinas WHERE identificador = ag_rec.oficina;
               fam := NULL;
               DBMS_OUTPUT.PUT_LINE(rpad(ag_rec.nombre,20) || '|' || rpad(fam,20) || '|' || rpad(ofi,20));
               num_ag := num_ag + 1;
          END IF;
     END LOOP;
DBMS_OUTPUT.PUT_LINE('---------------------------------------------------------------');
     DBMS_OUTPUT.PUT_LINE('Número de agentes: ' || num_ag);
END lista_agentes;
/

Recuerda que para ejecutarlo desde SQL*Plus debes ejecutar las siguientes sentencias:

SQL>SET SERVEROUTPUT ON;
SQL>EXEC lista_agentes;